Las constantes en programación

En este capítulo voy a hablar sobre las constantes en programación. Una constante es un contenedor para datos como una variable, que contendrá un dato fijo. Se lo damos una vez en el programa y este no puede cambiar.

"Constante" en inglés se dice "Constant".

Hay lenguajes de programación que son muy estrictos con las constantes y estas no hay forma alguna de cambiarles el valor. Otros como Python y PSeInt utilizan realmente variables que se pueden modificar, pero que se escriben de forma especial para que quien programa las distinga de las variables.

Creando una constante en PSeInt

Te preguntarás para qué necesitas un contenedor siempre con el mismo valor. Pues la respuesta, es para cosas que no tienen que cambiar. Por ejemplo, la semana tiene 7 días. Si quieres representar este valor en un programa, puedes guardar un 7 en una constante. La constante PI, es una de las muchas constantes matemáticas que tienen un valor constante (no cambia), tal y como su nombre indica.

Algoritmo constantes
	// Definimos la constante
	Definir NUMERO_PI Como Real
	
	// Le asignamos el valor
	NUMERO_PI <- 3.14159265
	
	// Mostramos el valor en la consola
	Escribir NUMERO_PI
FinAlgoritmo

En la consola te saldrá el valor, como si fuera una variable.

Esta constante, la puedes utilizar para calcular el área de un círculo con un algoritmo. Vamos a dejar que sea el usuario el que indique el tamaño del radio en centímetros del círculo que quiere.

Si no sabes mucho de matemáticas y de geometría, no te preocupes, con el siguiente módulo empezaré a explicar este tipo de cosas con más detalle.

Algoritmo calcular_area_circulo
	// Definimos las variables y la constante
	Definir NUMERO_PI Como Real
	Definir radio Como Real
	Definir area Como Real
	
	// Le asignamos el valor a la constante PI- Siempre es el mismo
	NUMERO_PI <- 3.14159265

	// Le pedimos el valor  del tamaño del radio en cm al usuario
	Escribir "Introduzca en cm, el tamaño del radio del círculo: "
	Leer radio
	
	// Calculamos el área con esta fórmula matemática: A=PI*r^2
	area <- NUMERO_PI * radio ^ 2
	
	// Mostramos el área en la consola
	Escribir "El área del círculo es ", area
FinAlgoritmo

Ahora, en la consola, tenemos una calculadora de áreas de círculo. Le podemos poner el tamaño en cm que queramos, con o sin decimales.

La fórmula matemática del cálculo de áreas de círculos, puede parecer apta para un científico o matemático profesional. Sin embargo, si la analizas, verás que no hay porque tenerle miedo.
A=PI*r^2 lo podemos traducir como: area = 3.14159265 x radio x radio. Que en el ejemplo, radio es 2, así sería: area = 3.14159265 x 2 x 2.
Más fácil de entender, ¿verdad?

Si hacemos esto con variables, el resultado es el mismo, pero la idea, es diferenciar claramente lo que es un valor que no debe cambiar y lo que si. Si a la constante PI le damos un valor de 10, el cálculo de este algoritmo, sería erróneo.

Constantes predefinidas del lenguaje

En los diferentes lenguajes de programación, vamos a encontrar una serie de constantes predefinidas. Estas constantes, forman parte del lenguaje, y las podemos utilizar. Solo hay que conocerlas.

PSeInt tiene una constante predefinida llamada PI, la podemos utilizar con solo poner su nombre en el algoritmo. Esto evitará que tengamos que poner su valor directamente, pudiendo cometer algún error al escribirlo o incluso si no lo recordamos.

Algoritmo calcular_area_circulo
	// Definimos las variables
	Definir radio Como Real
	Definir area Como Real

	// Le pedimos el valor  del tamaño del radio en cm al usuario
	Escribir "Introduzca en cm, el tamaño del radio del círculo: "
	Leer radio
	
	// Calculamos el área con esta fórmula matemática: A=PI*r^2
	area <- PI * radio ^ 2
	
	// Mostramos el área en la consola
	Escribir "El área del círculo es ", area
FinAlgoritmo

Con esto, tenemos el mismo algoritmo, pero está mucho más resumido. Hemos quitado la declaración y la asignación de la constante.

Verás que algunos decimales del resultado varían. Esto es porque mi constante PI tenía estos decimales:

3.14159265

Y la de PSeInt tiene lo mismo, pero dos decimales extra al final.

3.1415926536

¿Me he equivocado? No, la constante PI tiene muchos decimales. PI se ha calculado hasta más de 31 trillones de decimales, pero su número total de decimales es infinito.

Por este motivo, es imposible ponerlos todos. En el caso del resultado con la constante de PSeInt, el resultado en decimales es más preciso que con la que he escrito yo. Todo depende de la precisión que necesites. Incluso, si quieres más, haz tu constante con todos los decimales de PI que quieras. Aquí hay un documento que lleva el número entero (3) con 15.000 decimales detrás.

Curiosamente, en PSeInt, sus constantes predefinidas, están protegidas, no es posible reasignarlas:

Algoritmo prueba_pi
	PI <- 10
FinAlgoritmo

ERROR 86: Identificador no válido (PI).

Me da un error 86 diciendo que no puedo usar ese identificador para reasignarle un valor.